; two bad sorts
 
(define rand #f)
(define randint #f)
(let ((two31 #x80000000) (a (make-vector 56 -1)) (fptr #f))
  (define (mod-diff x y) (modulo (- x y) two31)) ; generic version
  ; (define (mod-diff x y) (logand (- x y) #x7FFFFFFF)) ; fast version
  (define (flip-cycle)
    (do ((ii 1 (+ ii 1)) (jj 32 (+ jj 1))) ((< 55 jj))
      (vector-set! a ii (mod-diff (vector-ref a ii) (vector-ref a jj))))
    (do ((ii 25 (+ ii 1)) (jj 1 (+ jj 1))) ((< 55 ii))
      (vector-set! a ii (mod-diff (vector-ref a ii) (vector-ref a jj))))
    (set! fptr 54) (vector-ref a 55))
  (define (init-rand seed)
    (let* ((seed (mod-diff seed 0)) (prev seed) (next 1))
      (vector-set! a 55 prev)
      (do ((i 21 (modulo (+ i 21) 55))) ((zero? i))
        (vector-set! a i next) (set! next (mod-diff prev next))
        (set! seed (+ (quotient seed 2) (if (odd? seed) #x40000000 0)))
        (set! next (mod-diff next seed)) (set! prev (vector-ref a i)))
      (flip-cycle) (flip-cycle) (flip-cycle) (flip-cycle) (flip-cycle)))
  (define (next-rand)
    (if (negative? (vector-ref a fptr)) (flip-cycle)
      (let ((next (vector-ref a fptr))) (set! fptr (- fptr 1)) next)))
  (define (unif-rand m)
    (let ((t (- two31 (modulo two31 m))))
      (let loop ((r (next-rand)))
        (if (<= t r) (loop (next-rand)) (modulo r m)))))
  (init-rand 19380110) ; happy birthday donald e knuth
  (set! rand (lambda seed
    (cond ((null? seed) (/ (next-rand) two31))
          ((eq? (car seed) 'get) (cons fptr (vector->list a)))
          ((eq? (car seed) 'set) (set! fptr (caadr seed))
                                 (set! a (list->vector (cdadr seed))))
          (else (/ (init-rand (modulo (numerator
                  (inexact->exact (car seed))) two31)) two31)))))
  (set! randint (lambda args
    (cond ((null? (cdr args))
            (if (< (car args) two31) (unif-rand (car args))
              (floor (* (next-rand) (car args)))))
          ((< (car args) (cadr args))
            (let ((span (- (cadr args) (car args))))
              (+ (car args)
                 (if (< span two31) (unif-rand span)
                   (floor (* (next-rand) span))))))
          (else (let ((span (- (car args) (cadr args))))
                  (- (car args)
                     (if (< span two31) (unif-rand span)
                       (floor (* (next-rand) span))))))))))

(define (shuffle x)
  (do ((v (list->vector x)) (n (length x) (- n 1)))
      ((zero? n) (vector->list v))
    (let* ((r (randint n)) (t (vector-ref v r)))
      (vector-set! v r (vector-ref v (- n 1)))
      (vector-set! v (- n 1) t))))
 
(define (stooge-sort lt? xv . args)
  (if (null? args) (stooge-sort lt? xv 0 (- (vector-length xv) 1))
    (let ((lo (car args)) (hi (cadr args)))
      (when (lt? (vector-ref xv hi) (vector-ref xv lo))
        (let ((t (vector-ref xv lo)))
          (vector-set! xv lo (vector-ref xv hi))
          (vector-set! xv hi t)))
      (when (< 1 (- hi lo))
        (let ((mid (quotient (- hi lo -1) 3)))
          (stooge-sort lt? xv lo (- hi mid))
          (stooge-sort lt? xv (+ lo mid) hi)
          (stooge-sort lt? xv lo (- hi mid))))))
      xv)
 
(define (sorted? lt? xs)
  (cond ((null? xs) #t)
        ((null? (cdr xs)) #t)
        ((lt? (cadr xs) (car xs)) #f)
        (else (sorted? lt? (cdr xs)))))
 
(define (bogosort lt? xs)
  (if (sorted? lt? xs) xs
    (bogosort lt? (shuffle xs))))
 
(display (stooge-sort < #(1 5 9 8 6 2 4 3 7))) (newline)
(display (bogosort < '(1 5 4 2 3))) (newline)

#(1 2 3 4 5 6 7 8 9)
(1 2 3 4 5)