[ create a new paste ] login | about

Project: programmingpraxis
Link: http://programmingpraxis.codepad.org/SlkN9AOJ    [ raw code | fork ]

programmingpraxis - Scheme, pasted on Mar 29:
; maximum difference in an array

(define (range . args)
  (case (length args)
    ((1) (range 0 (car args) (if (negative? (car args)) -1 1)))
    ((2) (range (car args) (cadr args) (if (< (car args) (cadr args)) 1 -1)))
    ((3) (let ((le? (if (negative? (caddr args)) >= <=)))
           (let loop ((x(car args)) (xs '()))
             (if (le? (cadr args) x)
                 (reverse xs)
                 (loop (+ x (caddr args)) (cons x xs))))))
    (else (error 'range "unrecognized arguments"))))

(define rand #f)
(define randint #f)
(let ((two31 #x80000000) (a (make-vector 56 -1)) (fptr #f))
  (define (mod-diff x y) (modulo (- x y) two31)) ; generic version
  ; (define (mod-diff x y) (logand (- x y) #x7FFFFFFF)) ; fast version
  (define (flip-cycle)
    (do ((ii 1 (+ ii 1)) (jj 32 (+ jj 1))) ((< 55 jj))
      (vector-set! a ii (mod-diff (vector-ref a ii) (vector-ref a jj))))
    (do ((ii 25 (+ ii 1)) (jj 1 (+ jj 1))) ((< 55 ii))
      (vector-set! a ii (mod-diff (vector-ref a ii) (vector-ref a jj))))
    (set! fptr 54) (vector-ref a 55))
  (define (init-rand seed)
    (let* ((seed (mod-diff seed 0)) (prev seed) (next 1))
      (vector-set! a 55 prev)
      (do ((i 21 (modulo (+ i 21) 55))) ((zero? i))
        (vector-set! a i next) (set! next (mod-diff prev next))
        (set! seed (+ (quotient seed 2) (if (odd? seed) #x40000000 0)))
        (set! next (mod-diff next seed)) (set! prev (vector-ref a i)))
      (flip-cycle) (flip-cycle) (flip-cycle) (flip-cycle) (flip-cycle)))
  (define (next-rand)
    (if (negative? (vector-ref a fptr)) (flip-cycle)
      (let ((next (vector-ref a fptr))) (set! fptr (- fptr 1)) next)))
  (define (unif-rand m)
    (let ((t (- two31 (modulo two31 m))))
      (let loop ((r (next-rand)))
        (if (<= t r) (loop (next-rand)) (modulo r m)))))
  (init-rand 19380110) ; happy birthday donald e knuth
  (set! rand (lambda seed
    (cond ((null? seed) (/ (next-rand) two31))
          ((eq? (car seed) 'get) (cons fptr (vector->list a)))
          ((eq? (car seed) 'set) (set! fptr (caadr seed))
                                 (set! a (list->vector (cdadr seed))))
          (else (/ (init-rand (modulo (numerator
                  (inexact->exact (car seed))) two31)) two31)))))
  (set! randint (lambda args
    (cond ((null? (cdr args))
            (if (< (car args) two31) (unif-rand (car args))
              (floor (* (next-rand) (car args)))))
          ((< (car args) (cadr args))
            (let ((span (- (cadr args) (car args))))
              (+ (car args)
                 (if (< span two31) (unif-rand span)
                   (floor (* (next-rand) span))))))
          (else (let ((span (- (car args) (cadr args))))
                  (- (car args)
                     (if (< span two31) (unif-rand span)
                       (floor (* (next-rand) span))))))))))

(define (shuffle x)
  (do ((v (list->vector x)) (n (length x) (- n 1)))
      ((zero? n) (vector->list v))
    (let* ((r (randint n)) (t (vector-ref v r)))
      (vector-set! v r (vector-ref v (- n 1)))
      (vector-set! v (- n 1) t))))

(define-syntax assert
  (syntax-rules ()
    ((assert expr result)
      (if (not (equal? expr result))
          (for-each display `(
            #\newline "failed assertion:" #\newline
            expr #\newline "expected: " ,result
            #\newline "returned: " ,expr #\newline))))))

(define (max-diff-quadratic xv)
  (define (x n) (vector-ref xv n))
  (let ((len (vector-length xv)))
    (let ((lo 0) (hi 0) (diff 0))
      (do ((i 0 (+ i 1))) ((= i len) (list lo hi diff))
        (do ((j (+ i 1) (+ j 1))) ((= j len))
          (let ((d (- (x j) (x i))))
            (when (< diff d)
              (set! lo i) (set! hi j) (set! diff d))))))))

(define (max-diff-linear xv)
  (define (x n) (vector-ref xv n))
  (let loop ((k 0) (lo 0) (hi 0) (min-lo 0) (max-d 0))
    (if (= (vector-length xv) k)
        (list lo hi max-d)
        (let* ((min-lo (if (< (x k) (x min-lo)) k min-lo))
               (d (- (x k) (x min-lo))))
          (if (< max-d d)
              (loop (+ k 1) min-lo k min-lo d)
              (loop (+ k 1) lo hi min-lo max-d))))))

(define (max-diff-test)
  (assert (max-diff-quadratic #(4 3 9 1 8 2 6 7 5)) '(3 4 7))
  (assert (max-diff-quadratic #(4 2 9 1 8 3 6 7 5)) '(1 2 7))
  (assert (max-diff-quadratic #(4 3 9 1 2 6 7 8 5)) '(3 7 7))
  (assert (max-diff-quadratic #(5 4 3)) '(0 0 0))
  (assert (max-diff-quadratic #(1 3 3)) '(0 1 2))
  (assert (max-diff-linear #(4 3 9 1 8 2 6 7 5)) '(3 4 7))
  (assert (max-diff-linear #(4 2 9 1 8 3 6 7 5)) '(1 2 7))
  (assert (max-diff-linear #(4 3 9 1 2 6 7 8 5)) '(3 7 7))
  (assert (max-diff-linear #(5 4 3)) '(0 0 0))
  (assert (max-diff-linear #(1 3 3)) '(0 1 2))
  (do ((i 0 (+ i 1))) ((= i 1000))
    (let ((x (list->vector (shuffle (range 1 25)))))
      (assert (max-diff-quadratic x) (max-diff-linear x))))
  (do ((i 0 (+ i 1))) ((= i 25))
    (let ((x (list->vector (shuffle (range 1 1000)))))
      (assert (max-diff-quadratic x) (max-diff-linear x)))))

(max-diff-test)


Output:
No errors or program output.


Create a new paste based on this one


Comments: