[ create a new paste ] login | about

Project: programmingpraxis
Link: http://programmingpraxis.codepad.org/io514WKh    [ raw code | output | fork ]

programmingpraxis - Scheme, pasted on Mar 30:
; credit card validation

(define (digits n . args)
  (let ((b (if (null? args) 10 (car args))))
    (let loop ((n n) (d '()))
      (if (zero? n) d
          (loop (quotient n b)
                (cons (modulo n b) d))))))

(define rand #f)
(define randint #f)
(let ((two31 #x80000000) (a (make-vector 56 -1)) (fptr #f))
  (define (mod-diff x y) (modulo (- x y) two31)) ; generic version
  ; (define (mod-diff x y) (logand (- x y) #x7FFFFFFF)) ; fast version
  (define (flip-cycle)
    (do ((ii 1 (+ ii 1)) (jj 32 (+ jj 1))) ((< 55 jj))
      (vector-set! a ii (mod-diff (vector-ref a ii) (vector-ref a jj))))
    (do ((ii 25 (+ ii 1)) (jj 1 (+ jj 1))) ((< 55 ii))
      (vector-set! a ii (mod-diff (vector-ref a ii) (vector-ref a jj))))
    (set! fptr 54) (vector-ref a 55))
  (define (init-rand seed)
    (let* ((seed (mod-diff seed 0)) (prev seed) (next 1))
      (vector-set! a 55 prev)
      (do ((i 21 (modulo (+ i 21) 55))) ((zero? i))
        (vector-set! a i next) (set! next (mod-diff prev next))
        (set! seed (+ (quotient seed 2) (if (odd? seed) #x40000000 0)))
        (set! next (mod-diff next seed)) (set! prev (vector-ref a i)))
      (flip-cycle) (flip-cycle) (flip-cycle) (flip-cycle) (flip-cycle)))
  (define (next-rand)
    (if (negative? (vector-ref a fptr)) (flip-cycle)
      (let ((next (vector-ref a fptr))) (set! fptr (- fptr 1)) next)))
  (define (unif-rand m)
    (let ((t (- two31 (modulo two31 m))))
      (let loop ((r (next-rand)))
        (if (<= t r) (loop (next-rand)) (modulo r m)))))
  (init-rand 19380110) ; happy birthday donald e knuth
  (set! rand (lambda seed
    (cond ((null? seed) (/ (next-rand) two31))
          ((eq? (car seed) 'get) (cons fptr (vector->list a)))
          ((eq? (car seed) 'set) (set! fptr (caadr seed))
                                 (set! a (list->vector (cdadr seed))))
          (else (/ (init-rand (modulo (numerator
                  (inexact->exact (car seed))) two31)) two31)))))
  (set! randint (lambda args
    (cond ((null? (cdr args))
            (if (< (car args) two31) (unif-rand (car args))
              (floor (* (next-rand) (car args)))))
          ((< (car args) (cadr args))
            (let ((span (- (cadr args) (car args))))
              (+ (car args)
                 (if (< span two31) (unif-rand span)
                   (floor (* (next-rand) span))))))
          (else (let ((span (- (car args) (cadr args))))
                  (- (car args)
                     (if (< span two31) (unif-rand span)
                       (floor (* (next-rand) span))))))))))

(define-syntax assert
  (syntax-rules ()
    ((assert expr result)
      (if (not (equal? expr result))
          (for-each display `(
            #\newline "failed assertion:" #\newline
            expr #\newline "expected: " ,result
            #\newline "returned: " ,expr #\newline))))))

(define (luhn n)
  (define (x2 n) (vector-ref #(0 2 4 6 8 1 3 5 7 9) n))
  (let loop ((ds (reverse (digits n))) (s 0) (two? #t))
    (cond ((null? ds)
            (let* ((sum (modulo s 10))
                   (check (if (zero? sum) 0 (- 10 sum))))
              (+ (* n 10) check)))
          (two? (loop (cdr ds) (+ s (x2 (car ds))) #f))
          (else (loop (cdr ds) (+ s (car ds)) #t)))))

(define (luhn? n)
  (define (x2 n) (vector-ref #(0 2 4 6 8 1 3 5 7 9) n))
  (let loop ((ds (reverse (digits n))) (s 0) (two? #f))
    (cond ((null? ds) (zero? (modulo s 10)))
          (two? (loop (cdr ds) (+ s (x2 (car ds))) #f))
          (else (loop (cdr ds) (+ s (car ds)) #t)))))

(define (luhn-test)
  (assert (luhn 4992739871) 49927398716)
  (assert (luhn? 49927398716) #t)
  (assert (luhn? 49927398715) #f)
  (do ((i 0 (+ i 1))) ((= i 10000))
    (assert (luhn? (luhn (randint #e1e8))) #t))
  (do ((i 0 (+ i 1))) ((= i 100))
    (assert (luhn? (luhn (randint (expt 10 i)))) #t)))

(luhn-test)

(define luhn #f)
(define luhn? #f)
(letrec ((x2 (lambda (n)
          (vector-ref #(0 2 4 6 8 1 3 5 7 9) n)))
         (luhn-sum (lambda (n two?)
           (let loop ((ds (reverse (digits n))) (s 0) (two? two?))
              (cond ((null? ds) s)
                    (two? (loop (cdr ds) (+ s (x2 (car ds))) #f))
                    (else (loop (cdr ds) (+ s (car ds)) #t)))))))
    (set! luhn (lambda (n)
      (let* ((sum (modulo (luhn-sum n #t) 10))
             (check (if (zero? sum) 0 (- 10 sum))))
        (+ (* n 10) check))))
    (set! luhn? (lambda (n)
      (zero? (modulo (luhn-sum n #f) 10)))))

(luhn-test)

(display (luhn 4992739871)) (newline)
(display (luhn? 49927398716)) (newline)


Output:
1
2
49927398716
#t


Create a new paste based on this one


Comments: