[ create a new paste ] login | about

Project: programmingpraxis
Link: http://programmingpraxis.codepad.org/STcpI9Cu    [ raw code | output | fork ]

programmingpraxis - Scheme, pasted on Apr 1:
; disjoint sets

(define (make-hash hash eql? oops size)
  (let ((table (make-vector size '())))
    (lambda (message . args)
      (if (eq? message 'enlist)
          (let loop ((k 0) (result '()))
            (if (= size k)
                result
                (loop (+ k 1) (append (vector-ref table k) result))))
          (let* ((key (car args))
                 (index (modulo (hash key) size))
                 (bucket (vector-ref table index)))
            (case message
              ((lookup fetch get ref recall)
                (let loop ((bucket bucket))
                  (cond ((null? bucket) oops)
                        ((eql? (caar bucket) key) (cdar bucket))
                        (else (loop (cdr bucket))))))
              ((insert insert! ins ins! set set! store store! install install!)
                (vector-set! table index
                  (let loop ((bucket bucket))
                    (cond ((null? bucket)
                            (list (cons key (cadr args))))
                          ((eql? (caar bucket) key)
                            (cons (cons key (cadr args)) (cdr bucket)))
                          (else (cons (car bucket) (loop (cdr bucket))))))))
              ((delete delete! del del! remove remove!)
                (vector-set! table index
                  (let loop ((bucket bucket))
                    (cond ((null? bucket) '())
                          ((eql? (caar bucket) key)
                            (cdr bucket))
                          (else (cons (car bucket) (loop (cdr bucket))))))))
              ((update update!)
                (vector-set! table index
                  (let loop ((bucket bucket))
                    (cond ((null? bucket)
                            (list (cons key (caddr args))))
                          ((eql? (caar bucket) key)
                            (cons (cons key ((cadr args) key (cdar bucket))) (cdr bucket)))
                          (else (cons (car bucket) (loop (cdr bucket))))))))
              (else (error 'hash-table "unrecognized message")) ))))))

(define (string-hash str)
  (let loop ((cs (string->list str)) (s 0))
    (if (null? cs) s
      (loop (cdr cs) (+ (* s 31)
        (char->integer (car cs)))))))

(define (make-disjoint-set hash eql? oops size)
  (let ((forest (make-hash hash eql? oops size)))
    (define (make-set item) ; car is parent, cdr is rank
      (forest 'insert item (cons item 0)))
    (define (find item)
      (let ((parent (car (forest 'lookup item))))
        (if (eql? item parent) item
          (let ((x (forest 'lookup (find parent))))
            (forest 'insert item x)
            (car x)))))
    (define (union item1 item2)
      (let* ((root1 (find item1)) (root2 (find item2))
             (rank1 (cdr (forest 'lookup root1)))
             (rank2 (cdr (forest 'lookup root2))))
        (cond ((< rank1 rank2)
                (forest 'insert root1 (cons root2 rank1)))
              ((< rank2 rank1)
                (forest 'insert root2 (cons root1 rank2)))
              ((not (eql? root1 root2))
                (forest 'insert root2 (cons root1 rank2))
                (forest 'insert root1 (cons root1 (+ rank1 1)))))))
    (lambda (message . args)
      (case message
        ((enlist) (forest 'enlist))
        ((make-set) (apply make-set args))
        ((find) (apply find args))
        ((union) (apply union args))))))

(define djs (make-disjoint-set string-hash string=? #f 19))
(djs 'make-set "A")
(djs 'make-set "B")
(display (djs 'enlist))
(newline)
(djs 'union "A" "B")
(display (djs 'enlist))
(newline)
(display (djs 'find "A"))
(newline)
(display (djs 'find "B"))
(newline)


Output:
1
2
3
4
((B B . 0) (A A . 0))
((B A . 0) (A A . 1))
A
A


Create a new paste based on this one


Comments: